using words in array when lock another textbox on form

Hi Abdo

You can't use that line:

  If InStr(1, TextBox1.Value, ARR, vbTextCompare) > 0 Then

since the third argument of Instr must be a String (not a Variant or string array like your ARR).

You could either step through the array performing Instr in each string or use the If/ Else If approach in your first version of the code.

Revision 24 July 2023

In the attached revised file, I've replaced TextBox 1 with ComboBox1- this allows your array of words to be shown in a dropdown list.

The revised code relies on making ARR as a Public variable (so once initialised, it's visible to other procedures) and haveing Option Base 1 (so the first element of arrays ihas index 1 not the default of 0), for ease of understanding. These first bits are in bold and MUST precede the procedures.

The ComboBox (with ARR) makes it easy to choose what you want). The Select Case/ End Select is where you say what happens for each match. Please note that I've used the textbox property Enabled to "lock" the unwanted cells (rather than Locked, as you did)

The code below is commented for your benefit.

Option Base 1
Public ARR As Variant

Private Sub UserForm_Initialize()

    ' set up array
    ARR = Array("SALES INVOICE NO", "CASH PAID")
    ' populate combobbox drop down
    ComboBox1.List = ARR
    ComboBox1.SetFocus
End Sub


Private Sub ComboBox1_Change()

    Dim Mtch As String, n As Long

    Mtch = ""

    ' loop through array, looking for any matches
    For n = LBound(ARR) To UBound(ARR)
    ' if matched, set Mtch to True
        If InStr(1, ComboBox1.Value, ARR(n), vbTextCompare) > 0 Then
            ' stop on first match
            Mtch = ARR(n)
            Exit For
        End If
    Next n

    ' do actions for whatever was matched
    Select Case Mtch

      Case ARR(1) ' for SALES INVOICE
      TextBox2.Enabled = True
      TextBox2.SetFocus
      TextBox3.Enabled = False
      
      Case ARR(2) ' For CASH PAID
      TextBox2.Enabled = False
      TextBox3.Enabled = True
      TextBox3.SetFocus
        
       ' add other cases HERE
       
      Case Else ' if no match
      TextBox2.Enabled = False
      TextBox3.Enabled = False
    End Select

End Sub

You can add other elements to the array ARR (within the _Initialize routine) but then need to add another Case <<value>>  section to the Change procedure where I've indicated.

Hope this fixes your problem.