Excel red box around text macro

Michael

In the attached file, I've replaced all your recorded code with this (in Module1), in bold with added comments to explain what is happening:

Sub TICKMARK()
'
' TICKMARK Macro
'
' Keyboard Shortcut: Ctrl+Shift+E
'

Dim Edges() As Variant
'
'declare an array with outer edge types
Edges = Array(xlEdgeBottom, xlEdgeTop, xlEdgeRight, xlEdgeLeft)
'loop through array for edge types
For n = LBound(Edges) To UBound(Edges)
    'setting edges to the same
    With Selection.Borders(Edges(n))
        .LineStyle = xlContinuous
        .Color = vbRed
        .Weight = xlMedium
    End With
Next n

End Sub

To use it, select a range of cells (optionally adding multiple ranges by pressing Ctrl first and selecting) then press Ctrl+Shift+E- it will draw red borders around the outside of what you had selected.

REVISION 07 January 2023:

In view of your discussion comments about using shapes instead, the revised file has this new code (in Module 2) which does that and will first delete all your previous "tickmark" boxes then draw new ones around your new selection(s). It does so by setting the shape names as Tickmark0, Tickmark2 etc. then the first For Each loop used the Instr method to see which shapes are named Tickmark... and deletes them if so (leaving any other shapes in tact). Again the comments tell you what's happening:

Sub AddShapes()
'
' AddShapes Macro
' Removes/ adds shapes around selection(s)
'
' Keyboard Shortcut: Ctrl+Shift+Q
'
    Dim shp As Shape, Slct As Variant

    'delete existing Tickmark shapes
    For Each shp In ActiveSheet.Shapes
        If InStr(shp.Name, "Tickmark") > 0 Then shp.Delete
    Next shp
    ' capture user selection in an array
    Slct = Split(Selection.Address, ",")
    ' loop though selection address(es)
    For n = LBound(Slct) To UBound(Slct)
        'add rectangle with dimensions...
        With Range(Slct(n))
            Set shp = ActiveSheet.Shapes.AddShape(1, .Left, .Top, .Width, .Height)
        End With
        ' ... then set properties and distinctive name(s) for easy later deletion
        With shp
            .Fill.Visible = msoFalse
            .Line.ForeColor.RGB = RGB(255, 0, 0)
            .Line.Weight = 2
            .Name = "Tickmark" & n
        End With
    Next n

End Sub

Pick some cells then use Ctrl+Shift+Q to get new red shapes. Repeat to delete those and add new ones.

Hope this helps- if so, please mark this answer as Selected.