doesn't filter data when save new file

Mussa

In the attached, I've modified your code (with changes and comments in bold below).

Your .Autofilter combination won't work as you intend so I have extended the OUTrng to add a helper column containing and OR formula (for D or E isn't blank). Ten it's autofilterd on that helper column and visible cells copired to a new sheet.

Sub EXPORT_REPORT()
Dim wsData As Worksheet, StrPath As String
Dim OUTrng As Range

Application.DisplayAlerts = False
'For Each ws In ThisWorkbook.Worksheets
StrPath = ActiveWorkbook.Path & "\"

With ThisWorkbook
    Set OUTrng = .ActiveSheet.Range("A1").CurrentRegion
    ' ### add helper column then filter on that
    With OUTrng
        Set OUTrng = OUTrng.Resize(.Rows.Count, .Columns.Count + 1)
    End With
    ' filter for D and E = blank or 0
    With OUTrng
        ' add formula to helper column then filter on that
        .Columns(.Columns.Count).Formula = "=If(OR(D" & .Row() & ">0, E" & .Row() & ">0),TRUE, FALSE)"
        .AutoFilter .Columns.Count, "TRUE"
        ' add new sheet and copy filtered data to that
        Worksheets.Add.Name = "Report"
        .SpecialCells(xlCellTypeVisible).Copy Worksheets("Report").Cells(1, 1)
        .AutoFilter
        'delete helper columns
        .Columns(.Columns.Count).Delete
        ActiveSheet.Columns(.Columns.Count + 1).Delete
    End With
End With

x = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
ActiveSheet.Range("a2:a" & x) = Evaluate("row(1:" & x - 1 & ")")

    ' remove source sheet
    Worksheets("sheet1").Delete

    ActiveWorkbook.SaveAs Filename:= _
        StrPath & "REPORT " & Format(Application.WorksheetFunction.EoMonth(Date - 10, 0), "MM - YYYY") & ".xlsx", FileFormat:=51

Application.DisplayAlerts = True

ActiveWorkbook.Close SaveChanges:=False

End Sub

Hope this makes sense and fixes things for you.