cancel running macro based on condition

Leopard

I suggest you split cells in D (as above) but write them to an output array (which I've declared as OutArray below) before writing to E:H. That way, you can collect the addresses of "incorrect cells" which don't contain just 4 items (into a string variable I've called Not4). At the end, you cand add a test to check if there are no eroors (and write to the columns) or give a modified message so that the user knows which cells have an error.

Changes are in bold and comments added:

Sub Sample()
    Dim ws As Worksheet
    Dim LastRow As Long, i As Long
    Dim tmpArray() As String
    Dim OutArray As Variant, Not4 As String


    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        LastRow = .Range("D" & .Rows.Count).End(xlUp).Row
        ReDim OutArray(2 To LastRow, 1 To 4)
        For i = 2 To LastRow
            If InStr(1, .Range("D" & i).Value, " ") Then
                tmpArray = Split(.Range("D" & i).Value, " ")
                 'check there are four items in this row
                If UBound(tmpArray, 1) = 3 Then
                    OutArray(i, 1) = tmpArray(0)
                    OutArray(i, 2) = tmpArray(1)
                    OutArray(i, 3) = tmpArray(2)
                    OutArray(i, 4) = tmpArray(3)
                Else
                    ' if more or less than 4, capture cell address
                    Not4 = Not4 & "D" & i & " "
                End If

            End If
        Next i
        
        If Not4 = "" Then
            ' write Output to columns
            .Range("E2:H" & LastRow).Value = OutArray
            Else
            ' tell user of errors
            MsgBox "You can't  split  all  of  items  because  there  are  not  four items in cell(s) " & Not4 & Chr(13) & Chr(13) & "Please correct items or number of (space) separators "
        End If

    End With
End Sub

I've changed the items in your question file (so they contain only 4 items)- see attached file but added spaces in the second words in D7 and D13 (for test purposes). Note that if you have four "words" but they have a leading space, a trailing space or two spaces rather than 1 then the code will see MORE that 4 items (though some may be null strings i.e. the nothing between two adjacent spaces).

Hope this makes sense and fixes your problem.