Sort words copied from pdf for excel output to descending numbered order

Hi Alaya and welcome to the Forum

In the attached file I've used VBA to solve your problem (hopefully).

If you paste a string like:

   Nonmetallic Mineral Products; Furniture & Related Products; Plastics & Rubber Products; Primary Metals; Machinery; Wood Products; Fabricated Metal Products; Computer & Electronic Products;

into (merged) cell F2 then click the green button below it, the code in Module 1 (shown below) will run and add rank numbers in the column to the right of your "fixed" list in B3:B20. If there are 7 tiems, it'll be 7 to 1 but if there are 12, 12 to 1 etc. It will also put today's date in cell C1 (I assume the updates are weekly or monthly)

Furthermore if it doesn't match an item, a message box will tell you. (Try this by running the macro then in F2 make Wood Products read Wood2Products say then run the macro again.

I've added comments (in maroon, after the ' ) to give you clues on how this code works:

Option Base 1

Sub WordsToRank()

Dim NewRanks As Variant, m as Long, n as Long
Dim Found as Boolean, NotFound as String
Range("C1").Value = Date  ' add date
Range("C3:C20").Value = "" 'clear ranks

NewRanks = Split(Range("F2"), ";") ' extract the text between ; delimiters into an array

If Right(Range("F2").Value, 1) = ";" Then ReDim Preserve NewRanks(UBound(NewRanks) - 1) ' remove last array element perhaps
For m = LBound(NewRanks) To UBound(NewRanks) ' loop through data array then...

    Found = False
    For n = 3 To 20 'loop through fixed category rows
        If Trim(NewRanks(m)) = Trim(Range("B" & n).Value) Then 'try to match each element with items in fixed list
            Range("C" & n).Value = UBound(NewRanks) - m + 1 'set the rank in matched cell
            Found = True 'mark as matched
        End If
    Next n
    If Found = False Then NotFound = NotFound & vbLf & NewRanks(m) 'collect any matches not found
Next m

If NotFound <> "" Then 'say if the outcome wasn't wholly successful
    r = MsgBox("Done but please check spelling of fixed Category c.f. un-matched ISM data:" _
    & vbLf & NotFound, vbOKOnly, "Didn't match some ISM data")
    Else
    MsgBox "Done!" 'or say it was
End If

End Sub