copy data of invoice to data sheet

Leopard

As written, your macro copies cells FROM the Data sheet to Invoice (but your question implies that you want to copy from Invoice TO Data instead).

If so, you need to change the assignments so Rs is set to Invoice not Data (see changes in bold below):

Sub saveButton()
 Set Rs = Sheets("Invoice 2")
 Set ws = Sheets("DATA")
 LastRow = ws.Range("A" & Rows.Count).End(xlUp).Row + 1
  ws.Range("A" & LastRow) = Rs.Range("F2")
  ws.Range("B" & LastRow) = Rs.Range("F3")
  ws.Range("C" & LastRow) = Rs.Range("F4")
  ws.Range("D" & LastRow) = Rs.Range("F5")
  ws.Range("E" & LastRow) = Rs.Range("A" & LastRow)
End Sub

Then if the last used row in Data is 49 say, the macro will copy  F1, F3, F3 and F4 from Invoice 2 to Data sheet A50, B50, C50 and D50.

Data E50 however will get cell A50 from Invoice 2 (from =Rs.Range("A" & LastRow)  in bold italics above).

Hope this helps.

OK. Please try this code. Paste it to a standard code module.

Sub SaveButton_Click()
    ' 131

    Dim Inv         As Variant              ' Invoice data
    Dim Tmp         As Variant              ' Invoice items data
    Dim Items       As Variant              ' Tmp w/o "Taxed" column
    Dim R           As Long                 ' row (diverse uses)
    Dim C           As Long                 ' loop counter: Tmp, 2

    With Worksheets("Invoice 2")
        Inv = .Range("F3:F6").Value
        ' each row must have a value in column A
        R = .Cells(17, "A").End(xlDown).Row
        Tmp = .Range(.Cells(17, "A"), .Cells(R, "F")).Value
    End With

    ' remove data for column "Taxed" from the invoice items
    ReDim Items(1 To UBound(Tmp), 1 To UBound(Tmp, 2) - 1)
    For R = 1 To UBound(Tmp)
        For C = 1 To UBound(Items, 2)
            ' removes the next to last item in a row
            Items(R, C) = Tmp(R, C + IIf(C = UBound(Items, 2), 1, 0))
        Next C
    Next R

    Application.ScreenUpdating = False
    With Worksheets("DATA")
        R = .Cells(.Rows.Count, "E").End(xlUp).Row + 1
        .Range("A2:I2").Copy                ' format new cells like first row
        .Cells(R, "A").Resize(UBound(Items), UBound(Items, 2) + UBound(Inv)) _
                      .PasteSpecial xlPasteFormats
        .Cells(R, "A").Resize(1, UBound(Inv)).Value = Application.Transpose(Inv)
        .Cells(R, "E").Resize(UBound(Items), UBound(Items, 2)).Value = Items
    End With
    With Application
        .CutCopyMode = False
        .ScreenUpdating = True
    End With
End Sub

Edit 04 Dec 2020   ===============================

If you wish to delete the data in the "Invoice" sheet after copying please replace the first code block in the above procedure with the one below.

    With Worksheets("Invoice 2")
        With .Range("F3:F6")
            Inv = .Value
            .ClearContents
        End With
        ' each row must have a value in column A
        R = .Cells(17, "A").End(xlDown).Row
        With .Range(.Cells(17, "A"), .Cells(R, "F"))
            Tmp = .Value
            .ClearContents
        End With
    End With