Hide the Entire Excel Interface - Ribbon Menu, Quick Access Toolbar, Status Bar, and More

Add to Favorites
Author: | Edits: don

How to hide every single part of the Excel interface with the click of a button!

This allows you to make really good looking professional interfaces without having to resort to UserForms.

In this tutorial, you will learn how to hide these parts of the Excel interface:

  • How to hide the Ribbon Menu.
  • How to hide the Quick Access Toolbar.
  • How to hide the formula bar.
  • How to hide the status bar.
  • How to hide the worksheet tabs.
  • How to hide the column and row headings.
  • How to hide the horizontal scroll bar.
  • How to hide the vertical scroll bar.
  • How to make the worksheet full screen.

Basically, everything will be gone except the title of the workbook and the barline, maximize/minimize, and close buttons on the top of the application window.

Hide the Excel Interface

Sub HideAll()
' Excel VBA Tutorial - https://www.TeachExcel.com
    
    ' Hide the Horizontal Scroll Bar
    ActiveWindow.DisplayHorizontalScrollBar = False
    
    ' Hide the Vertical Scroll Bar
    ActiveWindow.DisplayVerticalScrollBar = False
    
    ' Hide the Row/Column Headings
    ActiveWindow.DisplayHeadings = False
    
    ' Hide the Worksheet Tabs
    ActiveWindow.DisplayWorkbookTabs = False
    
    ' Hide the Status Bar (bottom of the window)
    Application.DisplayStatusBar = False
    
    ' Hide the Formula Bar
    Application.DisplayFormulaBar = False
    
    ' Hide the Ribbon Menu and Quick Access Toolbar
    Application.ExecuteExcel4Macro "show.toolbar(""Ribbon"",False)"
    
    ' Display Full Screen
    'Application.DisplayFullScreen = True
 
End Sub

Show the Excel Interface

Sub ShowAll()
' Excel VBA Tutorial - https://www.TeachExcel.com
'
' Just reverse the options in the previous macro -> False becomes True
' and True becomes False.
 
    ' Exit Full Screen
    ' - If this was used to show full screen after other display settings
    '   were changed, then put it before those settings are changed back.
    '   Full-screen mode and normal mode maintain separate settings for
    '   these.
    'Application.DisplayFullScreen = False
 
    ' Show the Horizontal Scroll Bar
    ActiveWindow.DisplayHorizontalScrollBar = True
    
    ' Show the Vertical Scroll Bar
    ActiveWindow.DisplayVerticalScrollBar = True
    
    ' Show the Row/Column Headings
    ActiveWindow.DisplayHeadings = True
    
    ' Show the Worksheet Tabs
    ActiveWindow.DisplayWorkbookTabs = True
    
    ' Show the Status Bar (bottom of the window)
    Application.DisplayStatusBar = True
    
    ' Show the Formula Bar
    Application.DisplayFormulaBar = True
    
    ' Show the Ribbon Menu and Quick Access Toolbar
    Application.ExecuteExcel4Macro "show.toolbar(""Ribbon"",True)"
 
End Sub
 

Other Resources


Downloadable Files: Excel File

Question? Ask it in our Excel Forum


Our Excel Courses

  • Skill Level: All Levels
  • |
  • 5 hours+

How to make a fully featured professional form in Excel that is unbreakable. This includes how to use the form to store, view, edit, and delete data from a data storage worksheet.

  • Skill Level: All Levels
  • |
  • 2 hours

Send Emails from Excel using VBA and Macros. This course starts from the Basics and builds up to more advanced examples with attaching workbooks, worksheets, PDF's, automatically sending emails, including a signature, error handling, increasing speed, and more.