add text to pdf,excel files names

Kalil

In the attached, modified file I have made the changes( in bold below) to your main code in Module 2 so that:

1. the input "Amount" (= end of filename in your case) is passed to the SearchFiles Function WITHOUT the extension (".xls*")
2. that Function checks both  .xls and .pdf file types then returns a string which is split into an array called Arr (which is looped through using new count variable m).

Sub test()
    Dim myDir$, s$, suf$, x, n&
    Dim Arr As Variant, m As Long
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show Then myDir = .SelectedItems(1)
    End With
    If myDir = "" Then Exit Sub
    Do
        s = InputBox("Enter amount")
        If s = "" Then Exit Do
        ' make default any last suffix
        suf = InputBox("Enter word", , suf)
        If suf = "" Then Exit Do
        ' pass name WITHOUT extension (but check in Function)
        x = SearchFiles(myDir & "\", "*" & s) ' & ".xls*")

        If x <> "" Then
            ' split text into an array
            Arr = Split(x, ";")
            ' loop through array
            For m = 0 To UBound(Arr) - 1
                n = n + IIf(n, 1, 2)
                Cells(n, 2) = CreateObject("Scripting.FileSystemObject").GetBaseName(Arr(m))
                Cells(n, 3) = Arr(m)
                ' check/ rename file, using Trim to eliminate leading/trailing spaces
                If Not IsFileOpen(Trim(Arr(m))) Then
                    Name Trim(Arr(m)) As Trim(Application.Replace(Arr(m), InStrRev(Arr(m), "."), 0, " " & suf))
                    Cells(n, 1) = Cells(n, 2) & " " & suf
                Else
                    Cells(n, 4) = "Currently in USE " & Format(Now, "yyyy/mm/dd hh:mm:ss")
                End If
            Next m
            '  advise number of conversions or open files
            MsgBox ("Listed " & UBound(Arr) & " files.")
        Else
            MsgBox "Not found"
        End If
        If MsgBox("Do you want to continue in same folder?", vbQuestion + vbYesNo) <> vbYes Then Exit Do
    Loop
    ' resize columns
    Columns("A:D").AutoFit
End Sub

(I added a messgae after eacj successful check)

The Function SearchFiles now checks for both .xls* and .pdf extensions, changes in bold again, and returns a string like "file10.pdf; file10.xlsx" (if you chose Amount 10 say):

Function SearchFiles$(myDir$, myFileName$)
    Dim fso As Object, myFolder As Object, myFile As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    For Each myFile In fso.GetFolder(myDir).Files
        ' check all files for named extensions
        If (Not myFile.Name Like "~$*") * (myFile.Name <> ThisWorkbook.Name) _
        * ((myFile.Name Like myFileName & ".xls*") Or (myFile.Name Like myFileName & ".pdf")) Then
            ' add to string (with delimiter= ";")
            SearchFiles$ = SearchFiles$ & myDir & myFile.Name & "; "
            ' don't quit on first find but search all files
            'Exit Function
        End If
    Next
    For Each myFolder In fso.GetFolder(myDir).SubFolders
        SearchFiles = SearchFiles(myFolder.Path & "\", myFileName)
    Next
End Function

I made no changes to the Function IsFileOpen

Hope this fixes your problem- if so, please remember to mark this Answer as Selected.