open files in all of folders branches in directory

Hi again Speed.

You can use VBA's FSO (File System Object) to do this.

I think you are good enough at VBA to understand the method (using a function which loops through subfolders and calls itself iteratively)- please see my recent Answer under expanding code to populate files names within subfolders. You could start by opening the file there and clicking the button to select your folder "C:\Users\spp\Desktop\information\".

REVISION #1, 02 June 2025

I don't have your file or the UserForm you use (and source data) but please try this modified code. You'll need to replace the code in your file. I've added comments to help:

Dim i As Long

Sub ListBox1_Click()

    Dim FileRoot As String
    Dim objFldr As Object
    Dim objFSO As Object

    ' initialise "found" counter
    i = 0

    ' state target WITHOUT last \!
    Const FolderPath = "C:\Users\pc\Desktop\data"

    With ListBox1
        MsgBox .ListIndex & ": " & .List(.ListIndex, 2)
        FileRoot = .List(.ListIndex, 2)
    End With

    ' enable use of FSO
    Set objFSO = CreateObject("Scripting.FileSystemObject")

    ' get folder
    Set objFldr = objFSO.GetFolder(FolderPath)

    ' pass folder and root to the function
    LoopEachFolder objFldr, FileRoot

    ' quit FSO
    Set objFSO = Nothing

    ' fit results and tell user
    If i <> 0 Then
        MsgBox "Launched " & i & " files"
        Else
        MsgBox "File not found for selection= " & FileRoot
    End If
    'return to this file
    ThisWorkbook.Activate
End Sub


Function LoopEachFolder(fldFolder As Object, fRoot As String)

    Dim objFldLoop As Object

    ' check for xls file in this folder
    Fname = Dir(fldFolder & "\" & fRoot & ".xls*")

    If Fname <> "" Then
        ' open file
        Workbooks.Open FileName:=fldFolder & "\" & Fname
        ' increment the "found" counter
        i = i + 1
     End If

    ' check again for a pdf of that name
    Fname = Dir(fldFolder & "\" & fRoot & ".pdf")
    If Fname <> "" Then
        ' try to open pdf
        ActiveWorkbook.FollowHyperlink fldFolder & "\" & Fname
        ' increment the "found" counter
        i = i + 1
    End If

    ' Then check within the subfolders in this folder...
    For Each objFldLoop In fldFolder.subFolders
        '  run this function on each subfolder found
        LoopEachFolder objFldLoop, fRoot
    Next objFldLoop

End Function

(REVISION #2, 02 June 2025 - corrected the If block which opens a found pdf file.)

('REVISION #3, 04 June 2025 - corrected that If blockto resore increment ation of the "found" counter)

Note that:

1. the Dim i as Long statement needs to be at the top of the code behind your UserForm
2. the Function code will open xls and pdf files (of the sdame name), in case both exist
3. I've assumed that your LIstBox1 contains "root" file names which might be found in the main folder or any deeper subfolders (without the need to list all the files in that ListBox).

I hope this solves your issue. If so, please mark this Answer as Selected.