Populate items in combobox based on header

Malkal

In the attached revised file, I've modified your code to use a VBA Dictionary to eliminate duplicates in values (and to add only unique values to Combobox2 of your UserForm). See comments and changes in bold:

Private Sub ComboBox1_Change()

    Dim LastRow As Long, header As Range, lCol As Long, srcWS As Worksheet
    Dim dict As Object, n As Integer

    Set srcWS = Sheets("ppr")
    ' create a new empty dicionary
    Set dict = CreateObject("scripting.dictionary")

    LastRow = srcWS.Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    ' find last row of data table
    With srcWS.Cells(1, 1).CurrentRegion
        lCol = .Columns(.Columns.Count).Column
    End With
    ' clear CB2
    ComboBox2.Clear
    ' loop along row 1 in current region
    For Each header In srcWS.Range(srcWS.Cells(1, 1), srcWS.Cells(1, lCol))
        ' see if CB1 matches row header
        If ComboBox1 = header.Value Then
            ' if so, loop down column...
            For n = 2 To LastRow
                ' ... and use ditionary to find only unique values
                If Not dict.exists(Cells(n, header.Column).Value) Then
                    ' add these to dictionary and CB2
                    dict.Add Key:=Cells(n, header.Column).Value, Item:=""
                    ComboBox2.AddItem Cells(n, header.Column).Value
                End If
            Next n
        End If
    Next header

End Sub

Note that

1. you didn't need your variable foundheaders nor to disable screen updating (for a UserForm)
2. I used a different technique (involving CorrentRegion) to find the last column of the data table (and ignore your list of headings, currently in column H).

Hope this works well for you.