Loop until table column names

Hi again Amin

Please take care with your questions- you attached a file without your latest change (my recent addition of the Delete button code). The attached revised code includes that code and a revised code for CbSubCategory_Change - which populates the list using a singleloop rather than several If then loops per category as you had-as below:

Private Sub CbSubCategory_Change()

    Dim n As Long, s As Long    
    Dim deg2 As String, tName as String

    LB_01.RowSource = Empty

    deg2 = CbSubCategory.Value


    Select Case Me.comDepartment.Value

        Case "Food": tName = "T_Food"
        Case "Beverage": tName = "T_Beverage"
        Case "Shisha": tName = "T_Shisha"
        Case "Other": tName = "T_Other"
        ' do nothing if value isn't one of the above
        Case Else: Exit Sub
    End Select

    s = 0
    ' search in Department table, looking for matching subcategory
    With Data.ListObjects(tName)
        ' loop down contents
        For n = 1 To .ListColumns("Dep").DataBodyRange.Count
            ' if row matches Sub Category ...
            If UCase(deg2) = UCase(.ListColumns("Dep").DataBodyRange.Cells(n)) Then
                'then populate list
                LB_01.AddItem
                LB_01.List(s, 0) = .ListColumns("Code #").DataBodyRange.Cells(n)
                LB_01.List(s, 1) = .ListColumns("Item Name").DataBodyRange.Cells(n)
                LB_01.List(s, 2) = .ListColumns("Unit").DataBodyRange.Cells(n)
                LB_01.List(s, 3) = Format(.ListColumns("Cost").DataBodyRange.Cells(n), "$#,##0.00")
                LB_01.List(s, 4) = Format(.ListColumns("Selling").DataBodyRange.Cells(n), "$#,##0.00")
                LB_01.List(s, 5) = .ListColumns("Price").DataBodyRange.Cells(n)
                LB_01.List(s, 6) = ""
                LB_01.List(s, 7) = .ListColumns("Dep").DataBodyRange.Cells(n)

                s = s + 1
            End If
        Next n
    End With

    ' show the item number for the last item in list (if any)
    If s > 0 Then Me.txtCode.Value = Me.LB_01.List(s - 1, 0) + 1


End Sub

You'll see (in bold above) that the table is identified by name (using a modified version of your Select tname code from elsewhere in the UF) and the ListBox columns populated using column names as requested.

Hope this works well for you (I did only limited testing)- if so, please remember to mark this Answer as Selected.