Timer Vs Open Other Excel

Frex

The first problem is that your new macro in Module 3 must specify the full path and file name with the file extension so should read (change in bold):

Sub Ajuda()

'

' Ajuda Macro



'open the other file...

Workbooks.Open Filename:="C:\Users\SE80211\OneDrive - Repsol\Desktop\error 9\Help File.xlxs"



End Sub

I've done that in the attached file (but tested it on a path on my PC).

Secondly, the tutorial timer was written (I believe) to be a standalone file. It operates on the active workbook. If you launch a new file, that becomes the active workbook (and the macros will look for sheet 2 which does not exist in your Help file).

To get around that, you can make the references to ranges specific to that file. I've done that in the attached file by adding ThisWorkbook. before the references, so for Module 1 the changes (in bold) are:

Option Explicit


Public DownTime As Date


Sub SetTimer()

    ' Just set the time and allow Timer sub do the work

    ThisWorkbook.Worksheets("Sheet2").Range("S2").Value = "00:00:15"

    DownTime = Now + TimeValue("00:00:15")

End Sub


Sub ShutDown()

    Application.DisplayAlerts = False

    ThisWorkbook.Close SaveChanges:=True

End Sub

and in Module 2:

Option Explicit



Dim Interval As Date


Sub Timer()

    ' set timer value (one second)


    Interval = Now + TimeValue("00:00:01")


    If ThisWorkbook.Worksheets("Sheet2").Range("S2").Value <= 0 Then

        ' reached 0 with no running timer (so just need to quit)

        Call ShutDown

        Else

        ' if not 0, decrement S2

        ThisWorkbook.Worksheets("Sheet2").Range("S2") = DownTime - Now

        Application.OnTime EarliestTime:=Interval, Procedure:="Timer"

    End If

End Sub

Now (using the file attached) the timer should keep going (even if you launch and are looking at the Help file) but any activity in the Help file, the timer file or other Excel files may delay the closure of the timer file (as I said before).

Hope this fixes your problem. If so, please remember to mark this Answer as Selected.