copy data from specific sheets based on headers

Good try, Kalil, but I think you have aligned your columns so well in your sheets that you don't need to let your code search for matches. The code below will do what you want.

' if you are very good at coding you can omit 'Option Explicit'
' but if you are very good at coding you will never omit it.
Option Explicit

Sub Copy_Columns()
    ' 305

    ' all your variable names are without meaning
    ' the intention must be to make reading your code more difficult:
    ' In this you succeeded, but you were the one most suffering from the deficit.
    ' Dim cols, sh As Variant, sh2 As Worksheet, i, s As Long, c As Long, f As Range

    Dim WsInv   As Worksheet            ' "Inventory"
    Dim WsPort  As Worksheet            ' sheet "Export" or "Import"
    Dim Impex   As Long                 ' loop counter: Import to Export
    Dim Rs      As Long                 ' loop counter: source (Impex)rows
    Dim Rt      As Long                 ' target (Inventory) row

    Set WsInv = Sheets("INVENTORY")
    Application.ScreenUpdating = False

    Set WsPort = Worksheets("Import")
    For Impex = 1 To 2
        With WsPort
            ' start from row 2 to end of column A
            For Rs = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
                .Range(.Cells(Rs, "B"), .Cells(Rs, "E")).Copy
                With WsInv
                    Rt = .Cells(.Rows.Count, "B").End(xlUp).Row + 1
                    .Cells(Rt, "B").PasteSpecial Paste:=xlPasteValuesAndNumberFormats
                    If Impex = 2 Then
                        With .Cells(Rt, "E")
                            .Copy Destination:=.Offset(0, 1)
                            .ClearContents
                        End With
                    End If
                    .Range(.Cells(Rt, 1), .Cells(Rt, "F")).Interior _
                           .Color = Array(16247773, 15123099)(Impex - 1)
                End With
            Next Rs
        End With
        Set WsPort = Worksheets("Export")
    Next Impex

    With Application
        .ScreenUpdating = False
        .StatusBar = "Done"         ' this will appear at the bottom left corner
    End With
End Sub