Need help is Error on Application.Transpose

Tom

Your line emailList = Application.Transpose.. should work (if Email1 is a column header in the named table and named sheet) but  I suggest you avoid this appraoch which sends a single email addressed to all email addresses. Better in my opinion to send an email per parent.

If your table has a column header named "Student" then this modified code will create an email per student. It will send them from Outlook once you comment out the .Display line and uncomment the .Send line. Things to change (possibly) are in bold below:

Sub IndivEmails()

Dim outlookApp As Object
Dim emailItem As Object
Dim emailSubject As String, emailBody As String
Dim emailTo As String, emailList As Variant
Dim n As Long 'varibble for row in table

Set outlookApp = CreateObject("outlook.Application")

With Worksheets("Email Sheet")

For n = 1 To .Range("TBLEmailList[Email1]").Count

    ' send an individual email

    emailSubject = "Re-registration at IES has not been completed yet."
    ' use this copperplate text (edit to suit before running macro)
    emailBody = "Kindly complete registration of your student before 30 July 2021. You can do so online at online at " _
        & "registration @ies.com" & " or by return of a paper registration form." & vbNewLine _
        & "If you have any questions, please call ####### on ######## during office hours."
    ' add student name from table column
    emailBody = "Dear parent/guardian of " & .Range("TBLEmailList[Student]").Cells(n) & vbNewLine & vbNewLine & emailBody

    emailTo = .Range("TBLEmailList[Email1]").Cells(n)

    Set emailItem = outlookApp.CreateItem(0)

    With emailItem

        .To = emailTo
        .CC = ""
        .BCC = ""
        .Subject = emailSubject
        .Body = emailBody
        ' ### comment out Send during testing; uncomment and comment out Display for real send
        .Display
        '.Send

    End With
Next n
' say something happened
MsgBox n - 1 & " individual emails created/sent"
End With

End Sub