Don't understand Object required error in macro

When you record a macro, Excel will not qualify the objects it creates. A range is "qualified" by stating on which worksheet it exists, and a worksheet is "qualified" when the code specifies the workbook that it is in. A range is therefore "fully qualified" when both sheet and book are specified. In the absence of qualification Excel assumes the ActiveSheet which is always in the ActiveWorkbook.

When you let your code open another workbook Excel will make that new workbook the ActiveWorkbook and one of the worksheets in this workbook - by default the first one - will become the ActiveSheet. All your previously recorded code with unqualified ranges will now refer to the new ActiveSheet. Of course, there is no Shape on the substituted ActiveSheet. Therefore no Chart gets extracted from that non-existent Shape, and next time your code refers to the ActiveChart no such object exists, which is why we are here.

Below is the first part of your macro, reformated and comments added. As you see, at the end, I activated ThisWorkbook - the one containing the code - in the assumption that that was the ActiveWorkbook when you created the code. I didn't bother to activate the original worksheet because Excel will remember that sheet when the book is activated. Therefore your code should work again as it did before you added the new workbook. I couldn't test.

Sub GenerateChart()
    ' GenerateChart Macro

    Dim userSelectedFile    As Variant
    Dim NewBook             As Workbook

    ' First get the filename from the user
    userSelectedFile = Application.GetOpenFilename

    ' Check if the user selected a file.
    If userSelectedFile = False Then
        ' - False is returned if the user did not select a file.
        MsgBox "No file selected."
        Exit Sub
    End If          ' moved here from the bottom of the code


'    Else           ' remove this

    ' If here, a file was selected and it will be contained within the variable that
    ' we used above, userSelectedFile.
    ' Open the file here or do whatever you want with it.
    MsgBox "File selected: " & userSelectedFile

    Workbooks.OpenText Filename:=userSelectedFile, _
                       Origin:=437, StartRow:=1, _
                       DataType:=xlDelimited, _
                       TextQualifier:=xlDoubleQuote, _
                       ConsecutiveDelimiter:=True, Tab:=False, Semicolon:=False, _
                       Comma:=True, Space:=True, Other:=True, OtherChar:="]", _
                       FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3, 1), _
                                  Array(4, 1), Array(5, 1), Array(6, 1), Array(7, 1), _
                                  Array(8, 1), Array(9, 1), Array(10, 1)), _
                                  TrailingMinusNumbers:=True

    ' the newly opened workbook is now the ActiveWorkbook
    ' all following ranges are not qualified (= no sheet specified).
    ' Therefore they are specified for for the ActiveSheet, which,
    ' at this moment, is the first sheet of the new workbook.

    ' However, the next two lines are without purpose: Delete them
    Range("A:A,C:C").Select         ' select columns A and C - Why?
    Range("C1").Activate            ' Activate C1 - Why?

    ' This is the source of your problem:
    ' ====  ActiveSheet.Shapes.AddChart2(201, xlColumnClustered).Select  ====
    ' the ActivweSheet is in the new workbook.
    ' Therefore:- (2 new lines of code)
    Set NewBook = ActiveWorkbook
    ThisWorkbook.Activate

    ' and continue with your recorded code
    ActiveSheet.Shapes.AddChart2(201, xlColumnClustered).Select

Of course, now the new workbook exists and is open but no longer visible. I added a spare variable NewBook at the top of my snippet and assigned the newly opened workbook to it. Now you can switch between workbooks using NewBook.Activate and ThisWorkbook.Activate.

Actually, the very next thing you should now learn is not to do that. The macro recorder can't read your mind and therefore reads from your fingers as you type, and that leads to Activate and Select and code like this.

NewBook.Activate
Worksheets("Sheet1").Activate
Range("A:A").Select
Range("A2").Activate
MsgBox "Selected cell's value = " & ActiveCell.Value

The point is that the macro recorder needs to read your fingers but your fingers can express what's on your mind. Therefore you can replace the above with the one line here following.

MsgBox "Designated cell's value = " & NewBook.Worksheets("Sheet1").Range("A2").Value

Any recorded code should therefore be cleansed of all uses of the Selection object and the Select and Activate statements needed to create it. A worksheet doesn't need to be visible (activated) in order to be addressed for reading or writing. Replace the Selection object with Range objects.