Macro to read (Random) indexed cell to modify list question.

What a lovely idea you have there! Let me tell you right away that your intention is wholly possible. In the attached workbook I present another method, however. This is because once you start using VBA you would naturally choose between worksheet  and VBA functions and then you would start doing things differently.

Here is my idea. You don't need to use F9 anymore. Instead, you just click on D13 and the word changes. VBA is creating the random number.

And you don't need to plan on deleting any words. Instead, you just block them. If the random generator picks a blocked number it just goes right back and picks another. It's so fast, the user can't even notice. In that way you don't need to damage your database by deletions. You can unblock words again by simply deleting the word "blocked" in column C. 

To block a number you just double-click on a word that has come up (E13). In the attached workbook #2 in row 21 is blocked. You can also set blocks manually.  No need to worry about capitalization. The comparison is not case sensitive.

Here is the code. I have programmed it in simple terms so that you can easily follow and possibly modify it. Paste it to the code module of your Vocab List worksheet. That location is vital. The code won't work if pasted to another location. Refer to the attached workbook for guidance.

Option Explicit

' this constant is used in both procedures
Const FirstRow      As Long = 20    ' change to suit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    ' 224

    Dim Rng     As Range            ' range to search in
    Dim Fnd     As Range            ' cell where a match was found

    With Target
        If .Address(0, 0) = "E13" Then
            Set Rng = Range(Cells(FirstRow, "D"), Cells(Rows.Count, "D").End(xlUp))
            Set Fnd = Rng.Find(.Offset(0, -1).Value, LookIn:=xlValues, LookAt:=xlWhole)
            If Not Fnd Is Nothing Then
                Fnd.Offset(0, -1).Value = "Blocked"
            End If
        End If
        Cancel = True
    End With
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    ' 224

    Dim LastRow         As Long                 ' last used row
    Dim RowID           As Long
    Dim i As Long

    With Target
        If .Address(0, 0) = "D13" Then
            Randomize
            LastRow = Cells(Rows.Count, "D").End(xlUp).Row

            Do
                ' pick a number between FirstRow and LastRow
                RowID = Int(2 + Rnd * (LastRow - FirstRow + 1))

                ' return to pick another number of the chosen one is blocked
            Loop While StrComp(Cells(RowID, "C").Value, "blocked", vbTextCompare) = 0

            .Value = Cells(RowID, "D").Value
            .Offset(0, 1).Select
        End If
    End With
End Sub

Note that my code doesn't save the workbook. Therefore, after the user doubl-clicked on a few words to block them they will be blocked only during the current session and will be unblocked automatically if the user closes the workbook without saving. Saving the workbook makes the blocks permanent.

Let me know if you still want your own idea implemented. I shall be glad to assist.