create data for each invoice after issue invoice

Leap

The problem with your file is that in "sales", column A has TOTAL, DISCOUNT, PAID and NET in A35:A38 so your last row calculation lr became 38- (beyond your invoice item data).

In the attached sheet, those cells are moved to column E (merged with F). Now your calculation of lr can work. The code is further modified as below:

Sub J3v16()
Dim ws As Worksheet, nr As Long, lr As Long
Application.ScreenUpdating = False
Set ws = Sheets("sales")

    With ws
        lr = .Cells(.Rows.Count, 1).End(xlUp).Row
        If lr > 22 Then
            .Range("b23:g" & lr).Copy
            With Sheets("DATA")
                nr = .Cells(.Rows.Count, 2).End(xlUp).Row + 1
                .Range("D" & nr).PasteSpecial xlPasteValues
                .Range("A" & nr).Resize(lr - 22) = ws.Range("A23:A" & lr).Value
                .Range("B" & nr).Resize(lr - 22) = ws.Range("F7")
                .Range("C" & nr).Resize(lr - 22) = ws.Range("F9")
                .Range("J" & nr).Resize(lr - 22) = ws.Range("G35")
                '.UsedRange.Borders.Weight = 2
                '.Columns(7).Resize(, 4).NumberFormat = "0.00"
            End With
        End If
    End With

Application.CutCopyMode = False

Application.ScreenUpdating = True

MsgBox "Invoice values copied to DATA sheet"

End Sub

Note that I've commented out the formatting you applied- it's better to format DATA ahead of its population. Also this macro does little so there's no real advantage in turning Application.ScreenUpdating off and on.

I leave you to clear (parts of) your invoice after the transfer.

Have a good weekend!