copy data from userform to sheet with multiple tools

Speed

The attached (working) version of your sheet demonstrates the simplified code below.

My idea to simplify your code is to make the control name in the userform to include the destination cell, with the short type separated by an underscore (so <short code>_<destination cell>)- this underscore is vital to the code.

If you add a new control (or change a destination), you need to follow that pattern (and include where you wnat the value to be on Invoice). The mapping between controls and cells is kept unique since VBA Explorer won't let you give two controls the same name.

That means your TextBox2 ("Customer_ID") becomes txt_E8, ComboBox1 becomes cmb_B16 etc. (I've done all that) and the code becomes just this: 

Private Sub CommandButton1_Click()
Dim ws As Worksheet
Dim Ctrl As Control, r As String, d As String

Set ws = Sheets("Invoice")

For Each Ctrl In UserForm1.Controls
 If TypeName(Ctrl) = "TextBox" Or TypeName(Ctrl) = "ComboBox" Then ' ignore Labels
    r = Ctrl.Name
    If InStrRev(r, "_") > 0 Then 'if _ in name, transfer to cell in name
        d = Right(r, Len(r) - InStrRev(r, "_"))
        ws.Range(d).Value = Ctrl.Value
    End If
 End If
Next Ctrl

ws.Range("G5") = Date 'set today's date in invoice

Me.Hide

End Sub

I've added a line to set cell "G5" to today's date in invoice. I removed the subs you had to add item numbers to the user form automatically (they didn't seem to work and it's easier just to type them I to the text boxes!) 

I've also removed the calculation of item totals  from your User form sub - these are now calculated and shown in the form (if there are values under Units and Price) when you move to another control. These totals are shown with two decimal places, normal for most currencies..That's done a sub like this (for each of the Unit and Price controls):

Private Sub txt_E16_AfterUpdate()
If txt_E16 <> "" And txt_F16 <> "" Then
    txt_G16 = Format(txt_E16 * txt_F16, "#,##0.00")
End If
End Sub

Hope this helps. Happy New Year too (in advance)!