How to set output range of a "repeat cell value" automatically

 Your code appears very different from the description you give of your intentions. Therefore I have ignored it. The code below does what I understood from your description. Note that this code must be pasted into a standard code module. That is one that you have to insert. Its default name will be like Module1.

Sub NewMultiplier()
    ' Variatus @TeachExcel 23 Feb 2019

    Dim Original As Variant
    Dim Repeats As Integer
    Dim Rng As Range

    Original = Range("A2").Formula
    Repeats = Int(Val(Range("B2").Value))
    Set Rng = Range("A2").Resize(Repeats - 1, 1).Offset(1)
    Rng.Value = Original
End Sub

Still working on the same presumption, I created another solution for you. The code below should be pasted into the code module of the worksheet on which you want the action. If you paste it to a standard code module, as is proper for the above code, it won't work.

Private Sub Worksheet_Change(ByVal Target As Range)
    ' Variatus @TeachExcel 24 Feb 2019

    Const TargetClm As Long = 2                     ' 2 = column B
                                                    ' (can't be < 2)
    Dim Original As Variant
    Dim Repeats As Integer
    Dim Rl As Long
    Dim Rng As Range

    With Target
        ' respond to a change in any cell in column
        ' TargetClm except row 1
        If (.Column = TargetClm) And (.Row > 1) Then
            Repeats = Int(Val(.Value))
            Set Rng = Cells(.Row, TargetClm - 1)    ' column to the left of TargetClm
            With Rng
                Rl = Cells(Rows.Count, .Column).End(xlUp).Row
                Original = .Formula
                If Len(Original) = 0 Then Exit Sub

                If Rl > .Row Then Range(.Offset(1), Cells(Rl, .Column)).ClearContents
                Set Rng = .Resize(Repeats - 1, 1).Offset(1)
            End With
            Rng.Value = Original
            .Offset(Repeats, -1).Select
        End If
    End With
End Sub

If installed in the correct location, as described above, this code will respond to an entry in any row below row 1 of the column designated as TargetClm at the top of the procedure. It will read the value to the left of it in the same row and replicate it as many times as the user has entered. In the left column, any existing values below the Target cell row will be deleted.