Send email w/Command Button and attach just the active sheet

I have commented your code to show why it produces a blank workbook. I then added code to create a workbook from the ActiveSheet and save it to the Desktop under the name you have specified. It seems that your existing code will then attach that workbook to the email it also creates.

Option Explicit

Private Sub CommandButton1_Click()
    Dim Rng As Range
    Dim xOutApp As Object
    Dim xOutMail As Object
    Dim xMailBody As String
    Dim wFile As String

    Set rng = Nothing
    On Error Resume Next        'hiding the crash won't prevent it
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
                vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    ' this will be the Desktop only if the workbook containing this code
    ' is on the Desktop
'    wFile = ThisWorkbook.Path & "\FSC-U006.xlsx"
'   The next line will set the path to the Desktop regardless
    wFile = CreateObject("WScript.Shell").SpecialFolders("Desktop") & "\FSC-U006.xlsx"

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With


'    Set newBook = Workbooks.Add             ' this creates a new blank workbook
'    newBook.SaveAs wFile                    ' and saves it as wFile
'    newBook.Close False                     ' no wonder it's blank

    ActiveSheet.Copy                         ' create a new workbook from the ActiveSheet
    With ActiveWorkbook
        .SaveAs wFile
        .Close
    End With

    ' you have to re-enable screen updating and events at some time
    ' why not now and here?
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

' OnErrorResumeNext ' Hiding the crash won't prevent it
    Set xOutApp = CreateObject("Outlook.Application")
    Set xOutMail = xOutApp.CreateItem(0)
    xMailBody = "Hello Sir/Ma'am," & vbNewLine & vbNewLine & _
                "You are receiving this email because your Annual ITEC Inventory is Due. Please see attached and validate the items listed for your account. If there are changes to be made i.e. DRMO, ROS, New items to be added, please annotate that in the Notes Column. Then have the primary and alternate digitally sign the inventory and return back to me." & vbNewLine & vbNewLine & _
                "If you have any questions please don't hesitate to contact me." & vbNewLine & vbNewLine & _
                "Thank you"

' On Error Resume Next ' hiding the crash won't prevent it
    With xOutMail
        .To = Recipients(Selection)
        .CC = ""
        .BCC = ""
        .Subject = "Annual ITEC Inventory Due"
        .Attachments.Add wFile
        .Body = xMailBody
        .Display 'or use .Send
    End With

    On Error GoTo 0
    Set xOutMail = Nothing
    Set xOutApp = Nothing
End Sub

Private Function Recipients(SelRng As Range) As String
    ' 25 Sep 2019
    Dim Fun As String
    Dim Cell As Range
    Dim Tmp As String
    On Error Resume Next        ' return a blank string if nothing was selected
    For Each Cell In SelRng.Columns(1).SpecialCells(xlCellTypeVisible)
        Tmp = Cell.Value
        ' test if the cell appears to contain an email address
        If InStr(Tmp, "@") Then
            If Len(Fun) Then Fun = Fun & ";"
            Fun = Fun & Tmp
        End If
    Next Cell
    Recipients = Fun
End Function

Edit 28 Sep 2019  =======================================

Referring to your comment, if you specify the fileformat Excel won't ask you which format to use. That would look like this (instead of the above). The specified file format will cause an xlsx extension.

    With ActiveWorkbook
        .SaveAs wFile, xlOpenXMLWorkbook
        .Close
    End With

BTW, you can modify the file either before you save it or after, such as locking cells and applying protetion. Before the SaveAs command the workbook has no name. Some actions which require it to have been saved will not be available. If you run against such a problem, perhaps when applying protection, make the changes after saving the file and close it with .Close True.