Sort Ascending by specific column some sheets excel vba

As you are looping through the worksheets, each one in turn is assigned to the variable wsheets. Your code does nothing with these sheets. Instead, it selects the worksheet "Set1", thereby making it the ActiveSheet, and then proceeds to sort the Activesheet - many times over.

The flaw is in the logic, of course. You don't want to sort the ActiveSheet. You want to sort "wsheet", whichever one that happens to be at the time. Therefore you might consider activating "wsheet" instead of "Set1", and that would actually work.

However, it sounds convoluted to make each sheet active so that you can sort the ActiveSheet, and it is. Once you have a handle on a sheet you can do with it whatever you like including activating it, sorting it, deleting it, copying it or modifying any cell in it. Of all those, and more, you are interested only in sorting. That is what the code below does.

Option Explicit

Sub SortByKAscending()
    ' 25 Jan 2018
    Dim Ws As Worksheet
    Dim SortRange As Range
    Dim Rl As Long
    Dim i As Integer
    
    Application.ScreenUpdating = False
    For Each Ws In ActiveWorkbook.Worksheets
        With Ws
            Application.StatusBar = "Sorting sheet " & .Name
            If .Name <> "Main" And .Name <> "Customers" Then
                ' determine the last used row in sort column
                Rl = .Cells(.Rows.Count, "K").End(xlUp).Row
                Set SortRange = Range(.Cells(2, "A"), .Cells(Rl, "M"))
                With SortRange
                    .Sort Key1:=.Cells(11), Order1:=xlAscending
                    .Cells.WrapText = True
                    .Rows.EntireRow.AutoFit
                End With
                i = i + 1
            End If
        End With
    Next Ws
    With Application
        .ScreenUpdating = True
        .StatusBar = ""
    End With
    MsgBox i & " worksheets were sorted.", _
           vbInformation, "Sorting complete."
End Sub