IF function & formulas

 The IF function consists of 3 parts as follows.

= IF ( [Argument] , [Argument is True], [Argument is False] )

Therefore this part of your formula = IF ( D3>E3, "3", "") is all that is needed and all that Excel can execute. Whatever follows must be ignored and therefore causes an error. Unfortunatley I can't figure out the description of your worksheet but I presume that you mean to nest the IFs, meaning

= IF ( [First argument], [True], [ELSE Second argument], [True], [ELSE Third argument], [True], [False] )))

The False result would occur only after all three arguments have been evaluated and none of them is True. That would leave you with this formula:-

=IF(D3>E3,"3",IF(D4<E4,"0",IF(D5=E5,"1","")))

Also, remember that Excel likes numbers, not text. 3 is a number, "3" is a word. I urge you to replace "3", "0" and "1" with 3, 0 and 1. The null string ("") as False result is also a string (text) and therefore unfortunate. It may cause an error if you wish to do calculations with it. If you come to that point it may help you to know that "" <> 0 but SUM("") = 0.

In response to the appended discussion I amend the formula to compare D3 and D4 in all three tests. I also modify the logic because it is assured that either D3 or D4 must be higher unless they are equal. The condition of having no result applies only if one of the parameters is missing (D3 or D4 being blank).

=IF(OR($D3="", $E3=""),"",IF($D3=$E3,1,IF($D3>$E3,3,0)))

Another way of doing the same thing is to use the SIGN() function which returns 1, 0 or -1 depending upon the sign (plus, minus or zero) of a number. Therefore SIGN(D3-E3)+1 would give you 2 for a win, 1 for a draw and 0 for a loss without the use of IF. But then you must use an IF to award the extra point for a win. The whole thing then looks like this:

=IF(OR($D3="", $E3=""),"",SIGN($D3-$E3) + IF($D3>$E3,2,1))

Paste eigher formula in F3 of your sheet and copy down.

The formula for your column G would be

=$D3-$E3