Random cell selection accross cell range when clicked

Please install this code in the code sheet of the worksheet on which you want the action. Note that the font color will be set, and a random selection made, when the sheet is activated. Change to another worksheet and back to see this action. After that the code does what you describe.

Option Explicit
    Const RangeAddress As String = "C2:J5"
    
Private Sub Worksheet_Activate()
    ShowRandomCell
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Rng As Range
    Dim CellId As Long
    Set Rng = Range(RangeAddress)
    If Not Application.Intersect(Target, Rng) Is Nothing Then
        If Target.Font.Color = vbBlack Then ShowRandomCell
    End If
End Sub
Private Sub ShowRandomCell()
    Static PreviousId As Long
    Dim Rng As Range
    Dim CellId As Long
    
    Set Rng = Range(RangeAddress)
        Rng.Font.Color = vbWhite
        Do
            Randomize
            CellId = Int(Rnd * Rng.Cells.Count) + 1
        Loop While CellId = PreviousId
        
        With Rng.Cells(CellId)
            .Font.Color = vbBlack
        End With
        PreviousId = CellId
End Sub

You can change the constant 'RangeAddress' to match your needs.

Try this:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Set TRange = Range("C2:J5")

If Not Application.Intersect(Target, TRange) Is Nothing Then

    TRange.Font.ColorIndex = 2

        randomCell1 = Int(Rnd * TRange.Cells.Count) + 1

    With TRange.Cells(randomCell1)
    .Select
    .Font.ColorIndex = 1
    End With

End If

End Sub

Put it into the worksheet where you want it to work (Alt + F11 then look to the left of the new window and double-click the worksheet that has the table of data and insert the code into the window that opens.)