Selected Answer
The code below will somewhat do the job.
Private Sub TeluguOnly()
Dim Exceptions() As Variant
Dim Txt As String
Dim Ch As Long
Dim i As Long, f As Long
Dim Rl As Long
Dim R As Long
Exceptions = Array(8206, 8209, 8234, 8236, -8194, -8253, -8676, -8677, -8698, _
-9072, -9105, -10176, -10179, -10180)
Application.ScreenUpdating = False
With ActiveSheet
Rl = .Cells(.Rows.Count, "A").End(xlUp).Row
' For R = 47 To 1 Step -1 ' for testing
For R = Rl To 1 Step -1 ' no header row
Txt = .Cells(R, "A").Text
If Len(Txt) Then
For i = Len(Txt) To 1 Step -1
Ch = AscW(Mid(Txt, i, 1))
If (Ch > 255) Or (Ch < 0) Then
For f = UBound(Exceptions) To 0 Step -1
If Ch = Exceptions(f) Then Exit For
Next f
If f < 0 Then Exit For
End If
Next i
Else
i = 0
End If
If i Then
' Debug.Print R, Ch, Txt ' for testing
' Exit For ' for testing
Else
.Rows(R).EntireRow.Delete
End If
Next R
End With
Application.ScreenUpdating = True
End Sub
"Somewhat" because it isn't perfect. Basically, it looks for unicoe characters. If it finds one it determines that the line is in Telugu language. While all Telugu characters are Unicode, not all Unicode characters are Telugu. Hence the list of exceptions. There are characters 8234 and 8236 which appear to be blank spaces which I found in lines 114:117. Most of the others I have identified are emojis. There are over a thousand emojis, and I have identified a dozen or less.
So, I have left some lines of code for testing purposes. The line "For R = 47 to 1 Step -1" can be activated only when the one below it is deactivated, and v.v. The intention, actually, is to look at line 47 in this case. It showed up as Telugu and I wanted to know which Unicode character was in it.
The other two lines marked "for testing" will print information about one line and then stop the program. The info will be printed to the Immediate window (Ctl+G in the VB Editor). It will print the row number, the Unicode number of the character which was found, and the line of text. That is how I found the emoji Unicode numbers and added them to Exceptions. You can find more recurring numbers like that and improve the filter eventually.
When the program isn't interrupted it will delete all lines which have no Unicode characters in them (exceptions and blank lines included). It will do its majic on the ActiveSheet (even if it is the one you didn't mean to mutilate), and it will work on the text in column A.
