Login to a Website using a Macro

Connect and login to a website using a macro in Excel.

This allows you to open a website and automatically login without having to do anything yourself; just run the VBA macro code from Excel.

Sections:

The Macro

Use the Macro

Notes

The Macro

Sub ExcelWebsiteLogin()
'TeachExcel.com macro to login to a website.

Dim ie      As Object
Dim frm     As Variant
Dim element As Variant


'Requires Microsoft Internet Controls to be activated. Tools > References > Microsoft Internet Controls
Set ie = New InternetExplorerMedium

'website page where the login form is located
ie.navigate "https://www.teachexcel.com/"

While ie.readyState <> 4: DoEvents: Wend

'ID of the login form
Set frm = ie.document.getElementById("login_form")

'Name of the form, if there is no ID for it.
If frm Is Nothing Then Set frm = ie.document.getElementsByName("login_form").Item(0)


If frm Is Nothing Then
   'Form not found.
   
   'Error message if the form was not found
   MsgBox "Login form not found."
   
   'Kill the internet explorer instance
   ie.Quit
   Set ie = Nothing

Else
   'Form found, proceed to fill it out and then submit it.
   
   'Display the browser
   ie.Visible = True

   'Go through elements in the browser
   For Each element In frm.elements
   
      On Error Resume Next
      
      'Input values into the form fields in the browser
      Select Case element.Name
         'username
         Case "email": element.Value = "email@gmail.com"
         'password
         Case "password": element.Value = "password"
      End Select
      
   Next

   'submit the form
   frm.submit

End If

End Sub

Use the Macro

Where to Install: Module

Enable Microsoft Internet Controls

This macro requires Microsoft Internet Controls to be enabled.

In the VBA Editor window (Alt+F11) go to Tools > References > Check next to Microsoft Internet Controls and hit OK.

Website to Visit

ie.navigate "https://www.teachexcel.com/"

Change https://www.teachexcel.com/ to the desired website.

Username and Password

'username
Case "email": element.Value = "email@gmail.com"
'password 
Case "password": element.Value = "password"

Change email@gmail.com to the correct username or email address for login.

Change password to the correct password to login.

In this example, the username and password are hard-coded into the macro. You can replace this with any number of methods to get the values. You could use a pop-up window to get the values, get values from the spreadsheet, or any number of other ways.

Notes

It is NOT advisable to store passwords anywhere where somenoe else can see them or access them and the last thing you want is to store a password in an Excel workbook and forget that it is there and then send it out to someone who shouldn't have it.

The password and username in this example are just for show and will not actually log you into any website.

You can store a password in a macro and then password protect that macro, here is a tutorial on that from us: Password Protect Excel VBA Macros. However, you should not consider this method secure if you send your workbook to another computer because there are methods for getting the data from a secured macro.

---